正在加载...
博主呓语:

批处理,一键开启、关闭IE代理服务器,自动切换IE代理,更改端口。(12.23更新)

Posted by GuuGe on 2015-10-18 10:55 Sunday 字号:
闲着无聊,为了配合shasocks.Qt5,COW此类没有自带IE代理设置的软件,花了点小时间,编写了个命令,免去要经常设置代理。
此批处理在一键/自动开关IE代理功能,再加多一个端口更改功能上去,基本就这样吧,放上来,做个备忘。

有需要的朋友可下载,或复制到记事本中,另存为*.bat文件也可以。

12月23日,更新修复更改端口的遗漏代码,并提供添加指定IP地址的功能代码。

之前下载的朋友,可重新下载,或右键BAT文件,选择编辑,清空原有代码内容,将更新的代码复制进去,保存即可。



以下为编写内容(12月23日更新):

@echo off 
title IE代理设置BAT。
set proxy="HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" 

:menu
echo.
echo ========================= 启用、关闭IE代理和更改端口 ==========================
echo.
echo 1:启用代理。
echo 2: 关闭代理。
echo 3: 更改端口并启用代理。
echo 4: 退出程序。
echo.
echo ============================================================== www.guuge.com ==
echo.
set /p id=请输入菜单相应序号 ,回车执行:
if %id%==1 goto do1  
if %id%==2 goto do2
if %id%==3 goto do3
if %id%==4 exit

:do1
::开启代理
reg add %proxy% /v "ProxyEnable" /t REG_DWORD /d 1 /f>nul
::IP及端口
reg add %proxy% /v "ProxyServer" /d "127.0.0.1:1080" /f >nul
::重启IE使代理生效
::taskkill /f /im iexplorer.exe
::start iexplorer.exe
echo.
echo 已启用IE代理。
echo.
pause
exit
 
:do2
reg add %proxy% /v "ProxyEnable" /t REG_DWORD /d 0 /f>nul
reg add %proxy% /v "ProxyServer" /d "" /f >nul
ipconfig /flushdns
echo.
echo 已关闭IE代理。
echo.
pause
exit

:do3
::更改IE代理端口
set /p port=请输入端口号,回车执行:
reg add %proxy% /v "ProxyEnable" /t REG_DWORD /d 1 /f>nul
reg add %proxy% /v "proxyServer" /d "127.0.0.1:%port%" /f >nul
::重启IE使代理生效
::taskkill /f /im iexplorer.exe
::start iexplorer.exe
echo.
echo 端口已更改为:%port%,并成功启用IE代理。
echo.
pause
exit

如果想添加手动更改IP地址功能,将如下代码替换:do3这整段代码即可。
:do3
::更改IE代理端口
set /p ip=请输入IP地址,回车确认:
set /p port=请输入端口号,回车执行:
reg add %proxy% /v "ProxyEnable" /t REG_DWORD /d 1 /f>nul
reg add %proxy% /v "proxyServer" /d "%ip%:%port%" /f >nul
::重启IE使代理生效
::taskkill /f /im iexplorer.exe
::start iexplorer.exe
echo.
echo 地址及端口已更改为:%ip%:%port%,并成功启用IE代理。
echo.
pause
exit

欢迎转载,请附上链接谢谢。
下载链接: http://pan.baidu.com/s/1bocr5kN
解压密码:www.guuge.com
 

评论:

某某好心市民
某某好心市民     2017-04-06 14:46   回复 2楼
已经按照你的意思写完了。你测试一下
@echo off
setlocal
set key="HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings"
set value=ProxyEnable
for /f "tokens=2* skip=2" %%a in ('reg query %key% /v %value%') do (
    set data=%%b
)
set /a newdata=1-data
reg add %key% /v %value% /t REG_DWORD /d %newdata% /f >nul

if %newdata%==1 reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /t REG_SZ /d 127.0.0.1:1080 /f >nul && echo 已经开启全局代理,并将代理服务器设置为127.0.0.1:1080
if %newdata%==0 (
    reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v "ProxyServer" /f >nul
    reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /t REG_SZ /d /f >nul
    echo 已经关闭代理,并将代理服务器设置为默认值
)
goto :eof
brucmao
brucmao   2017-05-14 12:06   回复
@某某好心市民:谢谢,不过要管理员运行才有效,在这里找到用管理员运行的代码,我加进去了。
@echo off
cacls.exe "%SystemDrive%\System Volume Information" >nul 2>nul
if %errorlevel%==0 goto Admin
if exist "%temp%\getadmin.vbs" del /f /q "%temp%\getadmin.vbs"
echo Set RequestUAC = CreateObject^("Shell.Application"^)>"%temp%\getadmin.vbs"
echo RequestUAC.ShellExecute "%~s0","","","runas",1 >>"%temp%\getadmin.vbs"
echo WScript.Quit >>"%temp%\getadmin.vbs"
"%temp%\getadmin.vbs" /f
if exist "%temp%\getadmin.vbs" del /f /q "%temp%\getadmin.vbs"
exit

:Admin
@echo off
setlocal
set key="HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings"
set value=ProxyEnable
for /f "tokens=2* skip=2" %%a in ('reg query %key% /v %value%') do (
    set data=%%b
)
set /a newdata=1-data
reg add %key% /v %value% /t REG_DWORD /d %newdata% /f >nul

if %newdata%==1 reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /t REG_SZ /d 127.0.0.1:1080 /f >nul && echo 已经开启全局代理,并将代理服务器设置为127.0.0.1:1080
if %newdata%==0 (
    reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v "ProxyServer" /f >nul
    reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /t REG_SZ /d /f >nul
    echo 已经关闭代理,并将代理服务器设置为默认值
)
goto :eof
brucmao
brucmao     2017-02-14 16:05   回复 1楼
这个能不能给改一下,点一下就设置ie代理为 127.0.0.1 1080
再点一下就关闭代理
不需要选择,后台运行。
GuuGe
GuuGe   2017-02-28 00:03   回复
@brucmao:可以实现的,不过,就大众,一般都默认端口为7777。
觉得没必要做成后台呀,做成类似UI的话,就失去意义了呀
brucmao
brucmao   2017-03-10 09:41   回复
@GuuGe:我的意思是我运行这个批处理,如果检测当前代理打开,就关闭代理。如果当前代理关闭,就打开代理。并自动添加代理地址 127.0.0.1 端口 1080

我现在用的IEProxyToggle 这个程序,有个运行参数是 -toggle

这个运行就是开启或者关闭代理。

但是这个有个问题是,并不会填入代理地址,需要事先在IE里填入代理地址和端口。
不方便。

发表评论: